Public Function M_G_Ip_GB50007_2002(DX As Double, DY As Double, Z As Double, Lo As Double, U As Double) As Double
'(DX, DY) 计算点相对于桩轴心的平面坐标, Z 计算点相对于地表的深度, Lo 桩长, u 土的泊松比
'计算集中单桩端阻力产生的附加应力系数,按GB50007-2002规范的Mindlin Geddes公式计算
Dim R As Double 'R-计算点离桩身轴线的水平距离
Dim N As Double, M As Double
Dim A As Double, B As Double
Dim IP1 As Double, IP2 As Double, IP3 As Double, IP4 As Double, IP5 As Double
'系数的计算
R = Sqr(DX * DX + DY * DY)
N = R / Lo: If N < 0.0000001 Then N = 0.0000001
M = Z / Lo
A = Sqr(N ^ 2 + (M - 1) ^ 2)
B = Sqr(N ^ 2 + (M + 1) ^ 2)
'单桩端阻力(集中力)作用下的附加应力系数计算
IP1 = (1 - 2 * U) * (M - 1) / A ^ 3
IP2 = -(1 - 2 * U) * (M - 1) / B ^ 3
IP3 = 3 * (M - 1) ^ 3 / A ^ 5
IP4 = (3 * (3 - 4 * U) * M * (M + 1) ^ 2 - 3 * (M + 1) * (5 * M - 1)) / B ^ 5
IP5 = 30 * M * (M + 1) ^ 3 / B ^ 7
M_G_Ip_GB50007_2002 = (IP1 + IP2 + IP3 + IP4 + IP5) / (8 * cPi * (1 - U))
End Function
Public Function M_G_Is1_GB50007_2002(DX As Double, DY As Double, Z As Double, Lo As Double, U As Double) As Double
'(DX, DY) 计算点相对于桩轴心的平面坐标, Z 计算点相对于地表的深度, Lo 桩长, u 土的泊松比
'计算单桩均布侧阻力产生的附加应力系数,按GB50007-2002规范的Mindlin Geddes公式计算
Dim R As Double 'R-计算点离桩身轴线的水平距离
Dim N As Double, M As Double
Dim A As Double, B As Double, F As Double
Dim IsJun1 As Double, IsJun2 As Double, IsJun3 As Double, IsJun4 As Double, IsJun5 As Double, IsJun6 As Double, IsJun7 As Double, IsJun8 As Double
If Lo = 0 Then M_G_Is1_GB50007_2002 = 0: Exit Function
'系数的计算
R = Sqr(DX * DX + DY * DY)
N = R / Lo: If N < 0.0000001 Then N = 0.0000001
M = Z / Lo
A = Sqr(N ^ 2 + (M - 1) ^ 2)
B = Sqr(N ^ 2 + (M + 1) ^ 2)
F = Sqr(N ^ 2 + M ^ 2)
'桩侧摩阻力沿桩身均匀分布情况下的附加应力系数计算
IsJun1 = 2 * (2 - U) / A
IsJun2 = -(2 * (2 - U) + 2 * (1 - 2 * U) * (M ^ 2 / N ^ 2 + M / N ^ 2)) / B
IsJun3 = (1 - 2 * U) * 2 * (M / N) ^ 2 / F
IsJun4 = -N ^ 2 / A ^ 3
IsJun5 = -(4 * M ^ 2 - 4 * (1 + U) * (M / N) ^ 2 * M ^ 2) / F ^ 3
IsJun6 = -(4 * M * (1 + U) * (M + 1) * (M / N + 1 / N) ^ 2 - (4 * M ^ 2 + N ^ 2)) / B ^ 3
IsJun7 = -6 * M ^ 2 * (M ^ 4 - N ^ 4) / N ^ 2 / F ^ 5
IsJun8 = -6 * M * (M * N ^ 2 - (M + 1) ^ 5 / N ^ 2) / B ^ 5
M_G_Is1_GB50007_2002 = (IsJun1 + IsJun2 + IsJun3 + IsJun4 + IsJun5 + IsJun6 + IsJun7 + IsJun8) / (8 * cPi * (1 - U))
End Function
Public Function M_G_Is2_GB50007_2002(DX As Double, DY As Double, Z As Double, Lo As Double, U As Double) As Double
'(DX, DY) 计算点相对于桩轴心的平面坐标, Z 计算点相对于地表的深度, Lo 桩长, u 土的泊松比
'计算单桩线性增长侧阻力产生的附加应力系数,按GB50007-2002规范的Mindlin Geddes公式计算
Dim R As Double 'R-计算点离桩身轴线的水平距离
Dim N As Double, M As Double
Dim A As Double, B As Double, F As Double
Dim IsSan1 As Double, IsSan2 As Double, IsSan3 As Double, IsSan4 As Double, IsSan5 As Double, IsSan6 As Double, IsSan7 As Double, IsSan8 As Double, IsSan9 As Double
If Lo = 0 Then M_G_Is2_GB50007_2002 = 0: Exit Function
'系数的计算
R = Sqr(DX * DX + DY * DY)
N = R / Lo: If N < 0.0000001 Then N = 0.0000001
M = Z / Lo
A = Sqr(N * N + (M - 1) * (M - 1))
B = Sqr(N * N + (M + 1) * (M + 1))
F = Sqr(N * N + M * M)
'桩侧摩阻力沿桩身线性增长情况下的附加应力系数计算
IsSan1 = 2 * (2 - U) / A
IsSan2 = -(2 * (2 - U) * (4 * M + 1) - 2 * (1 - 2 * U) * (1 + M) * M ^ 2 / N ^ 2) / B
IsSan3 = -(2 * (1 - 2 * U) * M ^ 3 / N ^ 2 - 8 * (2 - U) * M) / F
IsSan4 = -(M * N ^ 2 + (M - 1) ^ 3) / A ^ 3
IsSan5 = -(4 * U * N ^ 2 * M + 4 * M ^ 3 - 15 * N ^ 2 * M - 2 * (5 + 2 * U) * (M / N) ^ 2 * (M + 1) ^ 3 + (M + 1) ^ 3) / B ^ 3
IsSan6 = -(2 * (7 - 2 * U) * M * N ^ 2 - 6 * M ^ 3 + 2 * (5 + 2 * U) * (M / N) ^ 2 * M ^ 3) / F ^ 3
IsSan7 = -(6 * M * N ^ 2 * (N ^ 2 - M ^ 2) + 12 * (M / N) ^ 2 * (M + 1) ^ 5) / B ^ 5
IsSan8 = (12 * (M / N) ^ 2 * M ^ 5 + 6 * M * N ^ 2 * (N ^ 2 - M ^ 2)) / F ^ 5
IsSan9 = 2 * (2 - U) * Log((A + M - 1) * (B + M + 1) / (F + M) ^ 2)
M_G_Is2_GB50007_2002 = (IsSan1 + IsSan2 + IsSan3 + IsSan4 + IsSan5 + IsSan6 + IsSan7 + IsSan8 + IsSan9) / (4 * cPi * (1 - U))
End Function
