这是一本书上的,山岭隧道开挖模拟,DP模型,具体哪本忘记了,有些错误已经改过来了!
但是我不知道怎么上传附件!不好意思,直接贴了!
!ANSYS环境设定
fini
/cle
/filname,exm4
/title,The anslysis of the arch tunnel
!几何参数设定
*afun,deg !设定角度
!隧道分析范围参数
*set,x_zs,-50 !隧道左上角位置坐标
*set,y_zs,30
*set,x_yx,50 !隧道右下角位置坐标
*set,y_yx,-45
!加锚区锚设定
*set,num,30 !锚杆数
*set,th_s,0 !加锚起始角度
*set,th_f,180-th_s !加锚终止角度
*set,th,(th_f-th_s)/num !加锚角度间隔
!四心圆法建立隧道段面
*set,yx_1_x,0 !圆心1x坐标
*set,yx_1_y,0 !圆心1y坐标
*set,yx_2_x,0 !圆心2x坐标
*set,yx_2_y,11.37 !圆心2y坐标
*set,yx_3_x,3.34 !圆心3x坐标
*set,yx_3_y,0 !圆心3y坐标
*set,yx_4_x,-3.34 !圆心4x坐标
*set,yx_4_y,0 !圆心4y坐标
*set,r_1,5.8 !支护区系列圆1
*set,r_2,14.4 !支护区系列圆2
*set,r_3,2.67 !支护区系列圆3
*set,r_4,2.67 !支护区系列圆4
*set,r_jg_1,8.8 !加固区系列圆1
*set,r_jg_2,17.4 !加固区系列圆2
*set,r_jg_3,5.67 !加固区系列圆3
*set,r_jg_4,5.67 !加固区系列圆4
!梁杆单元参数区
*set,tl,0.25 !衬砌厚度
*set,rl,0.25 !锚杆半径
!材料参数设定
!围岩
e_r=1.5e9 !弹性模量,Pa
u_r=0.4 !泊松比
dens_r=1826.5 !密度,kg/m3
c_r=0.16e6 !凝聚力,Pa
fi_r=28 !内摩擦角
!c25混凝土
e_c=28.5e9 !弹性模量,Pa
u_c=0.2 !泊松比
dens_c=2449 !密度,kg/m3
!锚杆
e_a=170e9 !弹性模量,Pa
u_a=0.3 !泊松比
dens_a=7959 !密度,kg/m3
!定义单元类型
/prep7
et,1,3 !定义beam3单元
keyopt,1,6,1 !打开输出内力选项
et,2,42 !定义plane42单元
keyopt,2,3,2 !定义为平面应变问题
et,3,1 !定义link1单元
!定义材料属性
!衬砌
mp,ex,1,e_c !混凝土弹性模量
mp,prxy,1,u_c !混凝土泊松比
mp,dens,1,dens_c !混凝土密度
!围岩
mp,ex,2,e_r !围岩弹性模量
mp,prxy,2,u_r !围岩泊松比
mp,dens,2,dens_r !围岩密度
tb,dp,2 !定义DP材料
tbdata,1,c_r,fi_r !定义DP材料参数
!挖去土体的材料性质
mp,ex,3,e_r !弹性模量
mp,prxy,3,u_r !泊松比
mp,dens,3,dens_r !密度
tb,dp,3 !定义DP材料
tbdata,1,c_r,fi_r !定义DP材料参数
!锚杆
mp,ex,4,e_a !锚杆弹性模量
mp,prxy,4,u_a !锚杆泊松比
mp,dens,r,dens_a !锚杆密度
!定义实常数
r,1,tl,tl/12,tl !衬砌
r,2,3.14*(rl/2)**2 !锚杆
!实体建模
!隧道断面
k,1,yx_1_x,yx_1_y,0, !圆心1的位置
k,2,yx_2_x,yx_2_y,0, !圆心2的位置
k,3,yx_3_x,yx_3_y,0, !圆心3的位置
k,4,yx_4_x,yx_4_y,0, !圆心1的位置
k,101,yx_1_x,yx_1_y,10, !圆1法线上一点
k,102,yx_2_x,yx_2_y,10, !圆2法线上一点
k,103,yx_3_x,yx_3_y,10, !圆3法线上一点
k,104,yx_4_x,yx_4_y,10, !圆4法线上一点
circle,1,r_1,101 !生成圆
circle,2,r_2,102 !生成圆
circle,3,r_3,103 !生成圆
circle,4,r_4,104 !生成圆
lcsl,all !交线在交点处打断
lsel,s,,,23,26,1 !选择线
lsel,a,,,29,42,1 !选择线
lsel,a,,,5,6,1 !选择线
lsel,a,,,10,13,3 !选择线
lsel,a,,,44,45,1 !选择线
lsel,inve !反选
cm,zf,line !定义集合
cmsel,s,zf,line !选择集合
lsel,inve !反选
ldel,all,,,1 !删除线
allsel !选中所有元素
circle,1,r_jg_1,101 !生成圆
circle,2,r_jg_2,102 !生成圆
circle,3,r_jg_3,103 !生成圆
circle,4,r_jg_4,104 !生成圆
cmsel,s,zf,line !选择集合
lsel,inve !反选
lcsl,all !交线在交点处打断
lsel,s,,,49,58,1 !选择线
lsel,a,,,31,34,1 !选择线
lsel,a,,,37,42,1 !选择线
lsel,a,,,60,65,5 !选择线
lsel,a,,,61,64,3 !选择线
lsel,a,,,44,45,1 !选择线
lsel,a,,,5,6,1 !选择线
ldel,all,,,1 !删除线
allsel !选中所有元素
!隧道分析范围,水平方向100m,竖起方向75m,如图4_5所示。
rectng,x_zs,x_yx,y_zs,y_yx !生成矩形
asbl,all,all !用所有线分割面
!生成锚杆线:共30根锚杆,如图4_6所示。
asel,s,,,4 !选择4号面
csys,1 !激活柱坐标
wprota,,-90 !工作平面绕x轴旋转-90度
wprota,,,-th_s !平移工作平面
*do,i,1,num,1 !循环控制
wprota,,,-th !工作平面绕y轴旋转-th度
asbw,all !用工作平面切割选择集中所有面
*enddo !循环结束
wpcsys !工作平面与当前坐标系重合
asel,s,loc,y,th_s,th_f !利用坐标选择面
asel,inve !反选
aadd,all !面相加
allsel !选中所有元素
!定义两集合
asel,s,,,2 !支护区有锚区
lsla,s !由面选择线
lsel,r,loc,y,th_s,th_f !利用坐标选择线
cm,zf_mq,line !定义集合
asel,s,,,2 !支护无锚区
lsla,s !由面选择线
lsel,r,loc,y,th_f,th_s+360 !利用坐标选择线
cm,zf_wmq,line !定义集合
allsel !选中所有元素
!利用工作平面切割面
csys !激活总体笛卡儿坐标系
!左边竖直分割
wpcsys !工作平面与当前坐标系重合
wpof,-1.5*r_jg_1, !工作平面平移动1.5倍支护区圆1
wprota,,,-90 !工作平面绕y轴旋转-90度
asbw,all !用工作平面切割面
!右边竖直分割
wpcsys !工作平面与当前坐标系重合
wpof,1.5*r_jg_1, !工作平面平移动1.5倍支护区圆1
wprota,,,-90 !工作平面绕y轴旋转-90度
asbw,all !用工作平面切割面
!上边水平分割
wpcsys !工作平面与当前坐标系重合
wpof,,1.2*r_jg_1, !工作平面平移动1.2倍支护区圆1
wprota,,90 !工作平面绕x轴旋转90度
asbw,all !用工作平面切割面
!下边水平分割
wpcsys !工作平面与当前坐标系重合
wpof,,-1.2*r_jg_1, !工作平面平移动1.2倍支护区圆1
wprota,,90 !工作平面绕x轴旋转90度
asbw,all !用工作平面切割面
wpcsys !工作平面与当前坐标系重合
allsel !选中所有元素
!划分支护梁单元,如图4-8所示.
cmsel,s,zf_mq,line !选择集合
cmsel,a,zf_wmq,line !选择集合
esize,1 !确定划分尺寸
lmesh,all !划分所有线
allsel !选中所有元素
/efacet,1 !显示实常数
!对锚杆划分单元,如图4-9所示.
type,3 !指定3号单元
mat,4 !指定4号材料号
real,2 !指定2号实常数号
wpcsys !工作平面与当前坐标系重合
csys,1 !激活柱坐标
lsel,s,loc,y,th_s !选择线
*do,i,1,num-1,1 !循环控制
lsel,a,loc,y,th_s+th*i, !选择线
*enddo !循环结束
lsel,u,,,49,59,10 !不选择线号
lsel,u,,,68,69,1 !不选择线号
lsel,u,,,28
lmesh,all !划分当前选择,集中所有线
allsel !选中所有元素
!划分被挖土体有限元网格
type,2 !指定2号单元
mat,3 !指定3号材料
mshkey,0 !指定为自由网格划分
mshape,0 !指定为四边形网格划分
esize, !确定划分尺寸
amesh,2 !划分2号面
!控制尺寸
lsel,s,,,68,70,1 !选择线
lsel,a,,,72 !选择线
lsel,a,,,25,65,40 !选择线
lsel,a,,,28,59,31 !选择线
lesize,all,1 !确定划分尺寸
allsel !选中所有元素
esize,3 !确定其余线划分尺寸
!划分围岩的有限元网格
type,2 !指定2号单元
mat,2 !指定2号材料
asel,s,loc,x,1.5*r_jg_1,100*r_jg_1 !由位置选择面
amesh,all !划分面
allsel !选中所有元素
asel,s,loc,x,1.5*r_jg_1,100*r_jg_1 !由位置选择面
asel,inve !反选
asel,u,,,2 !不选择2号面
mshape,0 !指定为四边形网格划分
amesh,all !划分面
allsel !选中所有元素
!边界条件施加,施加边界条件后的隧道模型如图4-11所示.
csys,0 !激活总体笛卡儿坐标系
nsel,s,loc,x,x_zs !由位置选择节点
nsel,a,loc,x,x_yx !由位置选择节点
d,all,ux !约束x方向位移
allsel !选中所有元素
nsel,s,loc,y,y_yx !由位置选择节点
d,all,uy !约束y方向位移
allsel
!指定求解选项和输出选项
/solu !进入求解器
antype,static !指定为静力学求解器
pred,on !打开时间步长预测器
lnsrch,on !打开线性搜索
nlgeom,on !打开大变形求解
nropt,full !设定全N-R求解
outres,all,all !输出所有项,每一步都输出
nsub,7,10 !设定子步数为7,最大不超过10
!载荷步1,求解自重应力场
time,1
acel,,9.8 !施加重力加速度9.8
esel,s,type,,1,3,2 !选择1 3材料号的单元
ekill,all !杀死单元
esel,all !选中所有元素
esel,s,live !选择所有活单元
nsle,s !选择当前单元中所有节点
nsel,inve !反向选择
d,all,all !约束选择集 所有节点 所有自由度
allsel !选中所有元素
solve !求解
save,step1,db !保存为step1,db
!载荷步2,进行洞室全断面开挖 并施加支护
time,2
esel,s,mat,,3 !选择挖去部分的土体单元
ekill,all !杀死单元
esel,s,type,,1,3,2 !选择1 3材料号的单元
ealive,all !激活单元
nsle,s !选择当前单元中所有节点
ddele,all,all !将位移约束删除
esel,all !选中所有元素
esel,s,live !选择所有活单元
nsle,s !选择当前单元中所有节点
nsel,inve !反向选择
d,all,all,0 !将非活动节点约束
nsel,all !选中所有节点
esel,all !选中所有单元
solve !求解
save,step2,db !保存为step2,db
/post1 !进入后处理
!载荷步1
resume,'step1','db' !打开step1.db
file,'exm4','rst' !指定结果文件
set,1,last !读入第1个载荷步最后1个子步
esel,s,live !选择激活的单元
plnsol,u,sum,0,1.0 !显示合位移云图
plnsol,u,x !显示X方向位移云图
plnsol,u,y !显示y方向位移云图
plnsol,s,eqv !显示等效应力图
!图4-12显示了围岩合成位移去图,图4-13显示了围岩EQUIVALENT STRESS云图
!载荷步2
resume,'step2','db' !打开step2.db
file,'exm4','rst' !指定结果文件
set,2,last !读入第2个载荷步最后1个子步
!支护内力
esel,s,type,,1 !选择梁单元
etable,fx_i,smisc,1 !轴力
etable,fx_j,smisc,7
etable,fy_i,smisc,2 !剪力
etable,fy_j,smisc,8
etable,mz_i,smisc,6 !弯矩
etable,mz_j,smisc,12
plls,mz_i,mz_j,-0.5 !显示弯矩
plls,fx_i,fx_j,0.2 !显示轴力
plls,fy_i,fy_j,0.5 !显示剪力
!图4-14显示了支护的弯矩云图,图4-15显示了支护的轴力云图
!锚杆内力
esel,s,type,,3 !选择杆单元
etable,forx,smisc,1 !轴应变
plls,forx,forx,0.05 !显示轴力
etable,ybx,lepel,1 !轴应变
plls,ybx,ybx,0.05 !显示轴应变
!查看位移场(减去初始位移场)
resume,'step2','db' !打开step2.db
file,'exm4','rst' !指定结果文件
set,2,last !读入第1个载荷步最后1个子步
lcdef,1,1 !定义第1个荷载步为工况1
lcoper,sub,1 !当前载荷步的结果减去工况1的结果
esel,s,live !选择激活的单元
plnsol,u,sum !显示合位移云图
plnsol,u,x !显示X方向位移云图
plnsol,u,y !显示y方向位移云图
plnsol,s,eqv !显示等效应力图
